!khai bao ban dau
FINISH            !Ket thuc phien lam viec truoc
/CLEAR            !Xoa du lieu cu 
/PREP7            !Buoc vao bo giai tien xu ly - Preprocessor
ANTYPE,STATIC     !Khai bao loai bai toan phan tich 

!Dinh nghia loai phan tu - Element Type/Add/Solid/Quad 4 node 182
ET,1,PLANE182

!Khai bao cac lua chon bo xung phan tu (Option)
KEYOPT,1,1,0
KEYOPT,1,3,3
KEYOPT,1,6,0

!Dinh nghia tiet dien mat cat ngang 1 - Real constants/Add
R,1,1

!Dinh nghia vat lieu 1 - Material Props/Material Model/Structural/Linear/Elastic/Isotropic
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,73.1E3   
MPDATA,PRXY,1,,0.33  

!Tao hinh chu nhat
BLC4,0,0,150e-3,100e-3

!Tao 2 hinh tron 
CYL4,150e-3/2,0,5e-3
CYL4,150e-3/2,100e-3,5e-3

!Tru (-) DT hinh tron
ASBA,1,ALL           !1-DT hcn, lay all con lai - DT thu 1 (DT ban dau)

!Chia luoi theo muc (co 10 muc, min nhat la 1)
SMRTSIZE,1  !Kich thuoc co phan tu, do min
AMESH,ALL     !Tao luoi tren dien tich

!Khai bao dieu kien bien
NSEL,S,LOC,X,0           !Tao bo loc co toa do X=0
D,ALL,UX,0
NSEL,R,LOC,Y,0           !Them bo loc co toa do Y=0
D,ALL,UY,0
NSEL,ALL                 !Tra ve toan bo cac Keypoint

!Dat luc
SFL,2,PRES,-1e6      !Luc phan bo deu tren LINE (Line so 2)

!Tien trinh giai
FINISH    !Ket thuc khai bao
/SOLU     !Buoc vao tien trinh giai bai toan


!Tien hanh giai bai toan
SOLVE
/POST1
SET,LAST

!RNSOL,U                  !Hien kq thong so chuyen vi
!Xuatkq - Xuat tung kq theo mong muon
!LNSOL,U,SUM			! Xuat ket qua chuyen vi tong
PLNSOL,S,EQV			! Xuat ket qua ung suat tuong duong